Перенумерация документов

Перенумерация документов

 В своей практике я не раз сталкивался с ситуацией, когда пользователи 1С меняя нумерацию вручную убирали лидирующие нули и таким образом сбивали автоматическую нумерацию. Что делать? Как...

Нумерация документов

Нумерация документов

Достаточно отредактировать один раз номер. Например в 1С 8.2 Торговле. Описываем ситуацию. Отредактировали номер у документа, а следующий не записывается сообщая что номер не уникален или просто...

Выгрузка/Загрузка Пользователей системы 1С

Выгрузка/Загрузка Пользователей системы 1С

Внешняя обработка ВыгрузкаЗагрузкаПользователей.epf предназначена

Замена ссылок в документах и справочниках

Замена ссылок в документах и справочниках

Нередки случаи когда пользователи конфигураций 1С сталкиваются с проблемой возникновения дублей объектов информационной базы. Причины их возникновения мы рассматривать не будем,а рассмотрим как...

Свертка базы данных в 1С

Свертка базы данных в 1С

Свертка базы данных в 1С - это удаление данных, как правило документов, за прошлые отчётные периоды, по которым зафиксированы результаты хозяйственной деятельности, и данные не меняются.

Счет-фактуры выданные для указанных документов Реализация товаров и услуг

Счет-фактуры выданные для указанных документов Реализация товаров и услуг

Обработка автоматически создает документы “Счет-фактура выданный” для указанных документов “Реализация товаров и услуг” и проводит их.

Дата запрета изменения данных в 1с 8

Дата запрета изменения данных в 1с 8

Бухгалтерский и оперативный учет часто нуждается в блокировке данных за прошедший период. Особенно это актуально когда годовые отчеты сданы и документы все сверены. Период нужно "закрыть", чтобы...

Ошибка "Нарушена целостность структуры конфигурации"

Один из многих вариантов решения ошибки "Нарушена целостность структуры конфигурации".Если Вам довелось столкнуться с этой ошибкой обратитесь к специалисту 1С однозначно. Вариантов решения много,...

Удаление помеченных объектов

Удаление помеченных объектов

Модифицированная обработка «Удаление помеченных объектов»

Внутренняя ошибка компоненты dbeng8

Частая ошибка при активной работе всякого рода обработками. Поможет: Способ 1. В конфигураторе - Администрирование - Тестирование и исправление ошибок. Способ 2. Файл chdbfl.exe, который...

Реестр в ФСС

Реестр в ФСС

Данный обработка - внешний отчет, создан для конфигурации 1C "Зарплата и управление кадрами".  

Изменения конфигурации заблокированы средствами распределенной ИБ

Изменения конфигурации заблокированы средствами распределенной ИБ

Довольно редко, но встречается дополнительная блокировка информационной базы. При обновлении наталкивается что обновление и изменение поддежки не доступны, а рядом с замочком висит второй с...

Заполнение документа Реализация товаров и услуг по документу Заказ покупателя без учета остатков (УТ 10.3)

Заполнение документа Реализация товаров и услуг по документу Заказ покупателя без учета остатков (УТ 10.3)

В УТ 10.3 даже  при установленных флажках в Настройке дополнительных прав у пользователя Разрешить превышение остатка на складе и Разрешить превышение остатка товаров организации не заполняется...

Расходы будущих периодов (страхование)

Необходимо страхование гражданское отразить ввиде расходов будущих периодов, обязательно по разным подразделениям и статьям затрат (20 и 23, 25). Как это лучше реализовать в Бухгалтерии 2.0 Для...

Уполномоченные лица в 1С:Бухгалтерии 8

В 1С:Бухалтерии 8 появилась возможность в документах по реализации товаров и услуг и счетах-фактурах для автоматического вывода на печать указать ответственных лиц, подписывающих документы в полях...

Резервы по сомнительным долгам в 1С:Бухгалтерия 8

Внимание! В 1С:Бухгалтерия 8 ред. 2.0, начиная с релиза конфигурации 2.0.37.8, автоматизирован расчет резервов по сомнительным долгам в соответствии с п.70 Положения по ведению бухгалтерского учета...

Распределение входящего НДС при совмещении режимов налогообложения в программе "1С:Бухгалтерия"

При распределении НДС по косвенным расходам (совмещение ОСН и ЕНВД) в книгу покупок попадает не возмещаемая, а вся сумма входящего НДС и одновременно в книгу продаж невозмещаемая сумма. Есть две...

1С: Предприниматель 8

1С: Предприниматель 8

Программа "1С:Предприниматель 8" предназначена для индивидуальных предпринимателей (ИП). 1С Предприниматель - это готовое решение для ведения учета и составления отчетности. Программный продукт "1С...

Чтение и запись XML в языке 1С 8.3, 8.2

/// Как прочитать файл в формате XML через DOM /// в 1с 8.3, 8.2   &НаСервере Процедура ПрочитатьФайлXMLЧерезDOM(ПутьКФайлу)  

Пустая дата в 1С

В текстах модулей Если Дата = '00010101' Тогда Если Дата = '00010101000000' Тогда Если Дата = '0001-01-01' Тогда Если Дата = Дата(1, 1, 1) Тогда В запросах ГДЕ Дата =...

Как прибавить к дате день, месяц в 1С

СледующийДень = ТекущаяДата() + 60 * 60 * 24; ДобавитьМесяц(Дата(2005, 1, 31), 1); ДобавитьМесяц(Дата(2005, 2, 28), -1); КонецМесяца(ДобавитьМесяц(Дата(2005, 2, 28), -1)); Функция...

Работа с массивами в 1С 8.x

  Как создать массив? Как создать многомерный массив? Как добавить элементы в массив? Как определить размер массива? Как обратиться к элементу массива? Как перебрать элементы массива? Как...

Обновление распределенной информационной базы (РИБ)

Правильное обновление 1С при использовании обмена РИБ.

Построитель отчёта и таблица значений

Таблица значений была обработана построителем отчета 

Чтение данных с листа Excel

Функция ПрочитатьЛистExcel(ТЗ = Неопределено, ЛистЭксель = Неопределено,НомерПервойСтроки = 1, НомерПервойКолонки = 1, ВсегоСтрок = 0, ВсегоКолонок = 0) Экспорт

Функций по работе со строками

Здесь в краткой форме приведу функций по работе со строками:

GUID, ГУИД, уникальный идентификатор

«GUID (Globally Unique Identifier) — статистически уникальный 128-битный идентификатор. Его главная особенность — уникальность, которая позволяет создавать расширяемые сервисы и приложения без...

Дата запрета программно в УТ 10, КОРП и УПП

Если Вам необходимо программно изменить Дату запрета по своим параметрам. Добавляем в модуле сеанса:  КоличествоДней = 5; Попытка ДатаУстановки = НачалоДня(ТекущаяДата()) -...

Сократить ФИО

Функция ФИО(Сотрудник) Экспорт Перем ПолноеИмя, Фамилия, ИмяОтчество, Имя, Отчество; Перем ПозицияПервогоПробела, ПозицияВторогоПробела; ПолноеИмя = Сотрудник.Наименование; ПозицияПервогоПробела =...

Как сравнивать типы значений

В 1С есть две функции, с помощью которых можно производить операции с типами. 

Контроль остатков в УТ 10.3

Меню: Сервис - Пользователи - Настройка дополнительных прав: - Разрешить превышение остатков на складе; - Разрешить превышение остатков организации.

Учет выплаченных и полученных дивидендов в "1С:Бухгалтерии 8" ред. 3.0

Компания может распределять прибыль между участниками (акционерами) ежеквартально, раз в полгода или раз в год. О том, как изменился с 1 января порядок исчисления налогов с дивидендов по акциям мы...

Тип документа 1с 8.x

 В ЗАПРОСЕ: ... ДокументСсылка ССЫЛКА Документ.Поступление ... В ТЕКСТЕ: Если ТипЗнч(ДокументСсылка) = Тип("ДокументСсылка.Поступление")  Тогда

Настройка журнала регистрации в 1С 8.2 (8.3)

Журнал регистрации 1С — специальный механизм платформы 1С версий 8.2 и 8.3, который позволяет фиксировать работу пользователей с системой. С помощью журнала можно узнать кто и когда изменял объекты...

Выгрузка / Загрузка данных посредством текстовых (TXT) файлов

Для работы с текстовыми документами существуют три типа данных – ТекстовыйДокумент, ЗаписьТекста и ЧтениеТекста. Разница двух подходов состоит в способе загрузки документа: ТекстовыйДокумент...

Создание документа Операция Бух программно

ДокОперация = Документы.ОперацияБух.СоздатьДокумент();

Печать ценников любого размера, УТ 10.3, БП 2.0

Обработка предназначена для редактирования ценников.

Запросы в 1С

 Примеры запросов в 1С 8 Как в запросе 1с8 установить условие проверки периода на конец дня? Как правильно обрабатывать значения NULL в запросе 1С8? Как вывести результат запроса в табличный...

Как определить программно, существует ли у документа 1С требуемый реквизит

Вопрос Как определить программно, существует ли у документа требуемый реквизит Ответ В типовых конфигурациях 1С для этой цели используется функция «ЕстьРеквизитДокумента» общего модуля...

Копирование регистра 1с

Порой для уже отрытых конфигураций необходимо создать идентичную копию регистра для работы с ней по новым правилам установленным заказчиком. Часто такую задачу делают для аналитических отделов...

тип документа в запросе 1с

ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.ПоступлениеТоваровУслуг

Количество субконто счета %s превышает максимально возможное!

Количество субконто счета %s превышает максимально возможное!

Ошибка выходит при обновлении или добавлении нового счета в план счетов. Заходим в Конфигурацию. Находим Планы счетов необходимый нам список. Меняем "Максимальное кличество счетов"  

Форма выбора с отбором

СтандартнаяОбработка = Ложь; ФормаВыбора = Справочники.Номенклатура.ПолучитьФормуВыбора(, Элемент);Если ЗначениеЗаполнено(Значение) Тогда ФормаВыбора.ЭлементыФормы.СправочникСписок.ТекущаяСтрока =...

Как редактировать записи в списке (8.2, 8.3) ?

ЭлементыФормы.СписокДоговорыПайщиков.СпособРедактирования = СпособРедактированияСписка.ВСписке;

8.Х. Как добавить записи в независимый регистр сведений?

Случай 1.МенеджерЗаписи = РегистрыСведений.ЗначенияСвойствОбъектов.СоздатьМенеджерЗаписи(); МенеджерЗаписи.Объект = ПолеВводаНоменклатура; МенеджерЗаписи.Свойство =...

Список значений в языке 1С 8.3, 8.2 (в примерах)

&НаКлиенте Процедура ВыполнитьКод(Команда)       /// Как создать список значений в 1с 8.3, 8.2   Список = Новый СписокЗначений;       /// Как добавить элемент в список значений в 1с...

Тип Структура в языке 1С 8.3, 8.2 (в примерах)

&НаКлиенте Процедура ВыполнитьКод(Команда)       /// Как создать структуру (способ 1) в 1с 8.3, 8.2  

Таблица значений в языке 1С 8.3, 8.2 (в примерах)

&НаСервере Процедура ВыполнитьКодНаСервере()       /// Как создать таблицу значений в 1с 8.3, 8.2  

Работа с файловой системой в языке 1С 8.3, 8.2 (в примерах)

&НаСервере Процедура ЧтениеИЗаписьФайловНаСервере()       /// Как записать произвольное значение в файл в 1с 8.3, 8.2  

Функция Формат в языке 1С 8.3, 8.2 (в примерах)

&НаКлиенте Процедура ВыполнитьКод(Команда)       /// Как указать общее число цифр в 1с 8.3, 8.2

Тип Соответствие в языке 1С 8.3, 8.2 (в примерах)

&НаКлиенте Процедура ВыполнитьКод(Команда)       /// Как создать соответствие в 1с 8.3, 8.2  

Как вычислить формулу в строке?

ЧисловойРезультат=Вычислить(СтроковыйПараметр)

Изменение записей независимого регистра сведений

Вариант 1. Менеджер = РегистрыСведений.МойРегистр.СоздатьМенеджерЗаписи(); Менеджер.Контрагент = ИмяКонтраг1; Менеджер.Прочитать(); Если Менеджер.Выбран() Тогда ...

Транзакция

Разработчик может и сам создать транзакцию. Для выполнения действий в транзакции необходимо в код активировать её: НачатьТранзакцию(); По окончании транзакции её необходимо...

1С отборы в форме выбора

Процедура СобытиеНачалоВыбора(Элемент, СтандартнаяОбработка) СтандартнаяОбработка = Ложь; ФормаВыбора = Документы.Документ1.ПолучитьФормуВыбора(,...

Обнаружена незавершенная операция обновления конфигурации бд

Восстановление при некорректном обновлении конфигурации. Обнаружена незавершенная операция обновления конфигурации бд

Перенос строки

Пример: НаборСтрок = "Первая строка"+Символы.ПС+ "Вторая строка"+Символы.ПС+ "Третья строка"; В конструкции Символы также содержаться: ВК (CR) — возврат...

Табличное поле в 1С 8.x

Табличное поле в 1С 8.x Как запретить пользователю изменять порядок следования колонок в табличном поле? Как запретить пользователю изменять любые настройки колонок табличного поля? Как...

  • Перенумерация документов

    Перенумерация документов

  • Нумерация документов

    Нумерация документов

  • Выгрузка/Загрузка Пользователей системы 1С

    Выгрузка/Загрузка Пользователей системы 1С

  • Замена ссылок в документах и справочниках

    Замена ссылок в документах и справочниках

  • Свертка базы данных в 1С

    Свертка базы данных в 1С

  • Счет-фактуры выданные для указанных документов Реализация товаров и услуг

    Счет-фактуры выданные для указанных документов Реализация товаров и услуг

  • Дата запрета изменения данных в 1с 8

    Дата запрета изменения данных в 1с 8

  • Ошибка "Нарушена целостность структуры конфигурации"

  • Удаление помеченных объектов

    Удаление помеченных объектов

  • Внутренняя ошибка компоненты dbeng8

  • Реестр в ФСС

    Реестр в ФСС

  • Изменения конфигурации заблокированы средствами распределенной ИБ

    Изменения конфигурации заблокированы средствами распределенной ИБ

  • Заполнение документа Реализация товаров и услуг по документу Заказ покупателя без учета остатков (УТ 10.3)

    Заполнение документа Реализация товаров и услуг по документу Заказ покупателя без учета остатков (УТ 10.3)

  • Расходы будущих периодов (страхование)

  • Уполномоченные лица в 1С:Бухгалтерии 8

  • Резервы по сомнительным долгам в 1С:Бухгалтерия 8

  • Распределение входящего НДС при совмещении режимов налогообложения в программе "1С:Бухгалтерия"

  • 1С: Предприниматель 8

    1С: Предприниматель 8

  • Чтение и запись XML в языке 1С 8.3, 8.2

  • Пустая дата в 1С

  • Как прибавить к дате день, месяц в 1С

  • Табличный документ, текстовый документ в 1С 8.x

  • Функция Формат в языке 1С 8.3, 8.2 (в примерах)

  • Работа с массивами в 1С 8.x

  • Обновление распределенной информационной базы (РИБ)

  • Построитель отчёта и таблица значений

  • Чтение данных с листа Excel

  • Функций по работе со строками

  • GUID, ГУИД, уникальный идентификатор

  • Дата запрета программно в УТ 10, КОРП и УПП

  • Сократить ФИО

  • Как сравнивать типы значений

  • Контроль остатков в УТ 10.3

  • Учет выплаченных и полученных дивидендов в "1С:Бухгалтерии 8" ред. 3.0

  • Тип документа 1с 8.x

  • Настройка журнала регистрации в 1С 8.2 (8.3)

  • Выгрузка / Загрузка данных посредством текстовых (TXT) файлов

  • Создание документа Операция Бух программно

  • Печать ценников любого размера, УТ 10.3, БП 2.0

  • Запросы в 1С

  • Как определить программно, существует ли у документа 1С требуемый реквизит

  • Как программно изменить проводку в Регистре Бухгалтерии?

  • Копирование регистра 1с

  • тип документа в запросе 1с

  • Количество субконто счета %s превышает максимально возможное!

    Количество субконто счета %s превышает максимально возможное!

  • Форма выбора с отбором

  • Как редактировать записи в списке (8.2, 8.3) ?

  • 8.Х. Как добавить записи в независимый регистр сведений?

  • Список значений в языке 1С 8.3, 8.2 (в примерах)

  • Тип Структура в языке 1С 8.3, 8.2 (в примерах)

  • Таблица значений в языке 1С 8.3, 8.2 (в примерах)

  • Работа с файловой системой в языке 1С 8.3, 8.2 (в примерах)

  • Функция Формат в языке 1С 8.3, 8.2 (в примерах)

  • Тип Соответствие в языке 1С 8.3, 8.2 (в примерах)

  • Как вычислить формулу в строке?

  • Изменение записей независимого регистра сведений

  • Транзакция

  • 1С отборы в форме выбора

  • Обнаружена незавершенная операция обновления конфигурации бд

  • Перенос строки

  • Табличное поле в 1С 8.x

Работа с файловой системой в языке 1С 8.3, 8.2 (в примерах)

&НаСервере
Процедура ЧтениеИЗаписьФайловНаСервере()
 
    /// Как записать произвольное значение в файл в 1с 8.3, 8.2
 
    // любое сериализуемое (то есть превращаемое 
    // в строку и обратно) значение можно сохранять
    // в файл, например, массивы, списки значений, строки
    // структуры и т.д.
    Числа = Новый Массив;
    Числа.Добавить(35);
    Числа.Добавить(67);
    ЗначениеВФайл("c:\числа.txt", Числа);
    // эта функция работает только на сервере
 
    /// Как восстановить произвольное значение из файла в 1с 8.3, 8.2    
 
    ЧислаИзФайла = ЗначениеИзФайла("c:\числа.txt");
    Сообщить(ЧислаИзФайла[0]); // 35
    Сообщить(ЧислаИзФайла[1]); // 67
 
    /// Как записать текстовый файл в 1с 8.3, 8.2
 
    // работает как на сервере, так и на клиенте
    Текст = Новый ЗаписьТекста(
        "c:\привет.txt", // имя
        КодировкаТекста.ANSI, // кодировка
        Символы.ПС, // разделитель строк (необ.)
        Ложь // перезаписывать файл, а не дописывать в конец (необ.)
    );    
    Текст.ЗаписатьСтроку("Добро пожаловать!");
    Текст.ЗаписатьСтроку("Посторонним вход воспрещен.");
    Текст.Закрыть();
 
    /// Как прочитать текстовый файл в 1с 8.3, 8.2
 
    // работает как на сервере, так и на клиенте
    Текст = Новый ЧтениеТекста(
        "c:\привет.txt", // имя
        КодировкаТекста.ANSI, // кодировка
        Символы.ПС, // разделитель строк (необ.)
        ,
        Истина // монопольный режим (необ.)
    );
 
    // читаем пока есть что читать
    Пока Истина Цикл
        Строка = Текст.ПрочитатьСтроку();
        Если Строка = Неопределено Тогда
            Прервать;
        Иначе
            Сообщить(Строка);
        КонецЕсли;
    КонецЦикла;
 
КонецПроцедуры
 
&НаКлиенте
Процедура ОперацииНадФайлами(Команда)
 
    // для тестов создадим пустой файл
 
    Текст = Новый ЗаписьТекста("c:\file_src.txt");
    Текст.Закрыть();
 
    /// Как проверить существование файла в 1С 8.3, 8.2    
 
    ФайлНаДиске = Новый Файл("c:\file_src.txt");
    Если ФайлНаДиске.Существует() Тогда
        Сообщить("c:\file_src.txt существует");
    КонецЕсли;
 
    /// Как скопировать файл в 1с 8.3, 8.2 
 
    КопироватьФайл(
        "c:\file_src.txt", // что копируем
        "c:\file_dest.txt" // куда копируем
    ); // перезапишет, если уже есть такой файл
 
    /// Как переместить файл в 1с 8.3, 8.2 
 
    ПереместитьФайл(
        "c:\file_dest.txt",
        "c:\file_new.txt"
    ); // перезапишет, если уже есть такой файл
 
    /// Как найти файлы в каталоге в 1с 8.3, 8.2 
 
    // возвращает массив значений типа Файл
    МассивНайденныхФайлов = НайтиФайлы(
        "c:\", // где искать
        "*.txt", // маска поиска
        Ложь // если Истина, то будет искать и в подкаталогах
    );
 
    Для Каждого Файл Из МассивНайденныхФайлов Цикл
        Сообщить("Найден " + Файл.ПолноеИмя);
    КонецЦикла;
 
    /// Как удалить файл в 1с 8.3, 8.2
 
    // если файл readonly - будет ошибка
    УдалитьФайлы(
        "c:\file_new.txt"
    );
 
    /// Как удалить файлы в каталоге по маске в 1с 8.3, 8.2
 
    // поиск в каталоге нерекурсивный
    УдалитьФайлы(
        "c:\helpme1c", // заведомо не существующий каталог
        "*.txt" // маска для поиска удаляемых файлов
    ); // если опустить маску, то удалятся все файлы и каталог
 
    /// Как получить имя временного файла в 1с 8.3, 8.2
 
    Сообщить(
        ПолучитьИмяВременногоФайла()
    ); // например, c:\Temp\v8_11AE_4.tmp
 
    Сообщить(
        ПолучитьИмяВременногоФайла(".txt")
    ); // например, c:\Temp\v8_11AE_5.txt
 
    /// Как прочитать атрибуты файла в 1с 8.3, 8.2
 
    Ф = Новый Файл("c:\file_src.txt");
 
    // время последнего изменения файла
    Сообщить(Ф.ПолучитьВремяИзменения());
 
    // проверяем атрибут только чтение
    Сообщить(Ф.ПолучитьТолькоЧтение());
 
    // проверяем атрибут hidden (скрытность, невидимость)
    Сообщить(Ф.ПолучитьНевидимость());
 
    /// Как установить атрибуты файла в 1с 8.3, 8.2
 
    // меняем время последнего изменения файла
    Ф.УстановитьВремяИзменения(ТекущаяДата());
 
    // меняем атрибут только чтение
    Ф.УстановитьТолькоЧтение(Ложь);
 
    // меняем атрибут невидимости
    Ф.УстановитьНевидимость(Ложь);
 
    /// Как узнать размер файла в 1с 8.3, 8.2
 
    Сообщить(Ф.Размер()); // в байтах
 
    // Как узнать по пути файл это или каталог в 1с 8.3, 8.2
    Если Ф.ЭтоКаталог() Тогда
        Сообщить("Это каталог");
    ИначеЕсли Ф.ЭтоФайл() Тогда
        Сообщить("Это файл");
    КонецЕсли;
 
    /// Как вытащить расширение файла из его пути в 1с 8.3, 8.2
 
    Сообщить(Ф.Расширение); // .txt
 
    /// Как вытащить имя файла без расширения в 1с 8.3, 8.2
 
    Сообщить(Ф.ИмяБезРасширения); // file_src
 
КонецПроцедуры
 
&НаКлиенте
Процедура ОперацииНадКаталогами(Команда)
 
    /// Как создать каталог в 1с 8.3, 8.2
 
    // каталог может уже существовать
    СоздатьКаталог("c:\new_dir");
 
    // создадутся все подкаталоги
    СоздатьКаталог("c:\new_dir\2\3");
 
    /// Как проверить существование каталога в 1с 8.3, 8.2
 
    КаталогНаДиске = Новый Файл("c:\new_dir");
    Если КаталогНаДиске.Существует() Тогда
        Сообщить("Папка c:\new_dir существует");
    КонецЕсли;    
 
    /// Как удалить каталог вместе с содержимым в 1с 8.3, 8.2
 
    УдалитьФайлы("c:\new_dir");
    // мы опустили маску, поэтому удалятся все файлы
    // внутри каталога, а также сам каталог
 
    /// Как получить каталог временных файлов в 1с 8.3, 8.2
 
    Сообщить(
        КаталогВременныхФайлов()
    ); // например, c:\temp
 
КонецПроцедуры
 
&НаКлиенте
Процедура РаботаСВременнымХранилищем(Команда)
 
    // временное хранилище - объект, в который мы можем помещать
    // и считывать данные произвольного типа,
    // доступ к которому есть и на сервере и на клиенте
    // это позволяет передавать между сервером и клиентом
    // данные, которые иначе не передать
 
    /// Как сохранить произвольное значение во временное
    /// хранилище в 1с 8.3, 8.2
 
    Список = Новый СписокЗначений;
    Список.Добавить("Владивосток");
    Список.Добавить("Хабаровск");
    Список.Добавить("Петропавловск-Камчатский");
 
    АдресВХранилище = ПоместитьВоВременноеХранилище(
        Список // произвольные данные        
    );
 
    /// Как прочитать произвольное значение из временного
    /// хранилища в 1с 8.3, 8.2
 
    СписокИзХранилища = ПолучитьИзВременногоХранилища(АдресВХранилище);
    Если СписокИзХранилища = Неопределено Тогда
        Сообщить("Значение по этому адресу уже удалено из хранилища.");
    Иначе
        Сообщить(СписокИзХранилища[0]); // Владивосток
    КонецЕсли;
 
    /// Как перезаписать уже сохраненное значение во временном
    /// хранилище в 1с 8.3, 8.2
 
    Массив = Новый Массив;
    Массив.Добавить(10);
    Массив.Добавить(20);
 
    ПоместитьВоВременноеХранилище(
        Массив,
        АдресВХранилище
    );
 
    /// Сколько времени хранится значение, сохраненное во
    /// временном хранилище в 1с 8.3, 8.2
 
    // всё зависит от второго параметра функции ПоместитьВоВременноеХранилище
 
    // #1 если туда в качестве адреса был передан уникальный идентификатор формы
    // или уже существующий адрес в хранилище, то значение будет автоматически
    // удалено после закрытия формы
 
    // #2 если туда в качестве адреса передан уникальный идентификатор, не
    // являющийся уникальным идентификатором формы, то значение будет
    // автоматически удалено только после завершения сеанса пользвоателя    
 
    // #3 если адрес не указан, помещенное значение будет удалено после
    // очередного запроса сервера    
 
    // см. примеры ниже
 
    /// Как сохранить значение во временное хранилище на всё
    /// время жизни формы в 1с 8.3, 8.2
 
    ПоместитьВоВременноеХранилище(
        Массив,
        ЭтаФорма.УникальныйИдентификатор
    );
 
    /// Как сохранить значение во временное хранилище на всё
    /// время сеанса пользователя в 1с 8.3, 8.2
 
    АдресВХранилище = ПоместитьВоВременноеХранилище(
        Массив,
        Новый УникальныйИдентификатор
    );
 
    /// Как удалить значение из временного хранилища в 1с 8.3, 8.2
 
    УдалитьИзВременногоХранилища(АдресВХранилище);
 
    /// Как узнать является ли строка адресом во временном хранилище
    /// в 1с 8.3, 8.2
 
    Если ЭтоАдресВременногоХранилища(АдресВХранилище) Тогда
        Сообщить("Да, это адрес во временном хранилище.");
    КонецЕсли;
 
КонецПроцедуры
 
/// Как передать файл с клиента на сервер в 1с 8.3, 8.2
 
&НаКлиенте
Процедура ПередачаФайлаСКлиентаНаСервер(Команда)
 
    // создадим тестовый файл для передачи
    Текст = Новый ЗаписьТекста("c:\test.txt");
    Текст.ЗаписатьСтроку("Привет,");
    Текст.ЗаписатьСтроку("Мир!");
    Текст.Закрыть();
 
    ОповещениеОЗавершении = Новый ОписаниеОповещения(
        "ВыполнитьПослеПомещенияФайла", ЭтотОбъект
    );    
 
    НачатьПомещениеФайла(
        ОповещениеОЗавершении,
        , // адрес в хранилище
        "c:\test.txt", // имя файла
        Ложь, // интерактивно
        ЭтаФорма.УникальныйИдентификатор
    );
    // если опустить последний параметр, то помещенный файл
    // будет удален после очередного запроса сервера
    // а если указать - то только после удаления объекта формы
 
    // если нужно предоставить пользователю возможность
    // выбрать файл самому четвёртый параметр (интерактивно)
    // нужно установить в Истина
 
КонецПроцедуры
 
&НаКлиенте
Процедура ВыполнитьПослеПомещенияФайла(Результат, Адрес,
    ВыбранноеИмяФайла, ДополнительныеПараметры) Экспорт
 
    Если Результат Тогда
 
        // сохраним полученный адрес в реквизит формы
        АдресФайлаВХранилище = Адрес;
 
        Сообщить(
            "Наконец-то! Файл " +
            ВыбранноеИмяФайла + " передан на сервер и сохранён во " +
            "временном хранилище по адресу " + Адрес);
 
    Иначе
 
        Сообщить("Не удалось передать файл на сервер.");
 
    КонецЕсли;
 
КонецПроцедуры
 
/// Как прочитать файл на сервере из временного хранилища
/// в 1с 8.3, 8.2
 
&НаСервере
Процедура ПрочитатьФайлНаСервереИзХранилищаНаСервере()
 
    Если АдресФайлаВХранилище = "" Тогда
        Сообщить("Сначала нужно передать файл с клиента на сервер.");
        Возврат;
    КонецЕсли;
 
    ДвоичныеДанные = 
        ПолучитьИзВременногоХранилища(АдресФайлаВХранилище);
 
    Если ДвоичныеДанные = Неопределено Тогда
        Сообщить("Похоже файл уже был удалён из хранилища.");
        Возврат;
    КонецЕсли;
 
    ДвоичныеДанные.Записать("c:\server.txt");
 
    Текст = Новый ЧтениеТекста("c:\server.txt");
    Пока Истина Цикл
        Строка = Текст.ПрочитатьСтроку();
        Если Строка = Неопределено Тогда
            Прервать;
        Иначе
            Сообщить(Строка);
        КонецЕсли;
    КонецЦикла;
 
КонецПроцедуры
 
/// Как передать файл с сервера на клиент в 1с 8.3, 8.2
 
&НаКлиенте
Процедура ПередатьФайлССервераНаКлиент(Команда)
 
    Если АдресФайлаВХранилище = "" Тогда
        Сообщить("Сначала нужно сохранить файл на сервере.");
        Сообщить("Воспользуйтесь кнопкой 'Передача файла с клиента...'");
        Возврат;
    КонецЕсли;
 
    ОповещениеОЗавершении = Новый ОписаниеОповещения(
        "ВыполнитьПослеПолученияФайлов", ЭтотОбъект
    );
 
    ПолучаемыеФайлы = Новый Массив;
    ПолучаемыеФайлы.Добавить(
        Новый ОписаниеПередаваемогоФайла(
            "c:\from_server.txt", // куда сохранять на клиента
            АдресФайлаВХранилище // адрес в хранилище на сервере
        )
    );
 
    НачатьПолучениеФайлов(
        ОповещениеОЗавершении,
        ПолучаемыеФайлы,
        ,
        Ложь // интерактивно
    );
 
КонецПроцедуры
 
&НаКлиенте
Процедура ВыполнитьПослеПолученияФайлов(ПолученныеФайлы,
    ДополнительныеПараметры) Экспорт
 
    Для Каждого Файл Из ПолученныеФайлы Цикл
        Сообщить("Получен " + Файл.Имя + " из " + Файл.Хранение);
    КонецЦикла;
 
КонецПроцедуры
 
/// Скачать и выполнить эти примеры на компьютере

Похожие статьи:

Полезные обработки и отчеты

Полезные советы по БУ в 1С

JoomShaper Яндекс.Метрика Проверка PR и ТИЦ